Bạn đang muốn tìm cách để lọc dữ liệu trùng lặp trong Google Trang tính? Bài viết này sẽ cung cấp cho bạn 6 cách khác nhau để bạn có thể tìm và xóa những dữ liệu trùng lặp trong Google Trang tính.
Tìm dữ liệu trùng lặp trong Google Trang tính sử dụng công thức
Hãy bắt đầu với việc sử dụng công thức. tùy vào kết quả mà bạn muốn, các cách sử dụng công thức sẽ khác nhau.
Loại bỏ dữ liệu trùng lặp bằng cách sử dụng hàm UNIQUE
Giả sử bạn có một bảng dữ liệu như dưới đây:
Để lục những dữ liệu trùng lặp, bạn sử dụng hàm Unique như sau
=UNIQUE(A1:C11)
Công thức này trả về tất cả các lần xuất hiện đầu tiên sau khi đã loại bỏ các lần xuất hiện thứ 2, 3 của dữ liệu, v.v
Tuy nhiên, nếu bạn muốn lọc ra hàng dữ liệu duy nhất, hãy bỏ qua đối số thứ hai trong công thức nhưng thêm đối số thứ ba vào:
UNIQUE(range,[by_column],[exactly_once])- range — Dữ liệu bạn cần lọc.
- [by_column] — phương thức so sánh trùng theo cột (TRUE) hay theo hàng (FALSE). Mặc định là FALSE
- [exactly_once] — chỉ tính các giá trị xuất hiện 1 lần duy nhất trong danh sách (TRUE) hay các giá trị xuất hiện nhiều lần (FALSE). Mặc định là FALSE
Và đây là công thức để hiện thị các hàng chỉ xuất hiện 1 lần duy nhất:
=UNIQUE(A1:C11;;TRUE)
Bạn có thể thấy bảng bên phải ngắn hơn nhiều? Đó là vì UNIQUE đã xóa tất cả các hàng trùng lặp ra khỏi Google Trang tính, chỉ còn lại các hàng duy nhất không có dữ liệu trùng lặp.
Hàm COUNTIF cho Google Trang tính để đếm các bản sao
Nếu bạn không muốn xóa dữ liệu trùng lặp mà chỉ muốn đếm xem có bao nhiêu hàng trùng lặp, bạn có thể sử dụng hàm COUNTIF
Như công thức dưới đây, Tôi sử dụng công thức sau trong D2 và sau đó sao chép nó xuống các cột còn lại:
=COUNTIF($B$2:$B$11;$B2)
Trong trường hợp tổng số lần xuất hiện không phải là mục tiêu của bạn và bạn muốn biết liệu bản ghi cụ thể trong hàng xuất hiện lần thứ mấy, bạn chỉ cần thực hiện một điều chỉnh nhỏ.
Thay range từ ($B$2:$B$11) thành ($B$2:$B2).
=COUNTIF($B$2:$B2;$B2)
Công thức trong ví dụ trên chỉ đếm bản sao trong 1 cột B, để đếm bản sao là cả một hàng, bạn chỉ cần hoán đổi COUNTIF thành COUNTIFS và liệt kê mọi cột trong bảng của bạn cùng với các tiêu chí tương ứng của nó:
=COUNTIFS($A$2:$A$11;$A2;$B$2:$B$11;$B2;$C$2:$C$11;$C2)
Tìm các bản sao trong Google Trang tính và đánh dấu chúng trong cột trạng thái – Sử dụng hàm IF
Nếu chỉ hiển thị những con số như trên có thể là chưa đủ. Bạn có thể đánh dấu chúng bằng một cột trạng thái riêng. Sau đó bạn có thể lọc cột này sau để chỉ xem và xử lý các bản ghi trùng lặp hoặc duy nhất.
Đối với ví dụ này, bạn vẫn sẽ cần dùng một hàm COUNTIF nhưng lần này được bọc trong hàm IF. Bạn tham khảo công thức dưới đây:
=IF(COUNTIF($B$2:$B$11;$B2)>1,"Trùng","Không trùng")
Giải thích:
- Đầu tiên, COUNTIF tìm kiếm dữ liệu trùng lặp từ B2 trong toàn bộ cột B. Sau khi tìm thấy, nó sẽ tổng hợp chúng lại.
- Sau đó, IF kiểm tra tổng số mà COUNTIF có được. Nếu lớn hơn 1, nó trả về Trùng, ngược lại, là Không trùng.
Mẹo: Ngay sau khi đã tìm được dữ liệu theo cột trạng thái, bạn có thể lọc cột này để chỉ hiển thị dữ liệu trùng lặp
Bạn có thể đánh dấu các hàng trùng lặp – các hàng có tất cả các cột đều trùng nhau bằng cách:
- Sử dụng hàm COUNTIFS dò từng cột và chỉ đếm những hàng mà cả 3 bản ghi trong cả 3 cột đều giống nhau:
=COUNTIFS($A$2:$A$11;$A2;$B$2:$B$11;$B2;$C$2:$C$11;$C2) - Sau đó, sử dụng hàm IF bao lấy công thức đó. Nếu số lượng dữ liệu trùng vượt quá 1, sẽ trả về Trùng:
=IF(COUNTIFS($A$2:$A$11;$A2;$B$2:$B$11;$B2;$C$2:$C$11;$C2)>1;"Trùng";"không trùng")
Để bỏ qua lần xuất hiện đầu tiên và chỉ đánh dấu vào ô trạng thái lần xuất hiện thứ 2 trở đi, hãy tham khảo công thức sau:
=IF(COUNTIFS($A$2:$A2;$A2;$B$2:$B2;$B2;$C$2:$C2;$C2)>1;"Trùng";"")
Highlight dữ liệu trùng lặp trong Google Trang tính
Bạn có thế dễ dàng nhìn ra dữ liệu trùng lặp bằng cách highlight chúng bằng cách sử dụng định dạng có điều kiện
Đây là những gì bạn cần phải làm:
- Mở cài đặt định dạng có điều kiện: Định dạng> Định dạng có điều kiện.
- Chọn cùng dữ liệu bạn muốn lọc dữ liệu trùng lặp. Đối với ví dụ này, hãy để tôi bắt đầu với cột B.
- Trong Quy tắc định dạng, chọn công thức tùy chỉnh và nhập vào câu lệnh sau:
=COUNTIF($B$2:$B$11;$B2)>1
Khi đó, tất cả các bản ghi xuất hiện ít nhất hai lần trong cột B sẽ được tô màu bằng màu bạn đã chọn:
Nếu bạn muốn đánh dấu cả hàng trùng lặp, chỉ cần điều chỉnh lại phạm vi áp dụng của công thức là được:
Mẹo: Sau khi đánh dấu xong các mục trùng lặp, bạn có thể lọc dữ liệu Google Trang tính của mình theo màu:
- Bạn có thể lọc cột để chỉ hiển thị các ô có màu tô trắng. Bằng cách này, bạn sẽ ẩn các bản sao khỏi chế độ xem:
- Hoặc chỉ hiển thị các ô tô màu bằng cách chọn màu mà bạn muốn hiển thị.
- :
Sau đó bạn có thể chọn và xóa các hàng trùng lặp này khỏi Google Trang tính của bạn:
Các cách không cần công thức để tìm và xóa các bản sao trong Google Trang tính
Ngoài cách sử dụng công thức như trên, chúng ta vẫn còn có những công cụ khác có thể giúp bạn tìm thấy các dữ liệu trùng lăoj. Hai trong số chúng được thiết kế cho vấn đề cụ thể này.
Sử dụng Bảng tổng hợp (Pivot table) của Google Trang tính để đếm dữ liệu trùng lặp
Bạn có biết rằng bạn có thể sử dụng bảng tổng hợp từ Google Trang tính để đếm các bản sao không?
- Vào Chèn > Bảng tổng hợp, và chọn vùng dữ liệu mà bạn muốn sử lý rồi nhấn tạo
- Một Sheet Bảng tộc hợp sẽ được tạo ra. Trong Trình chỉnh sửa bảng tổng hợp, Nhấn nút Thêm ở mục Hàng rồi chọn hàng bạn muốn đếm dữ liệu trùng lặp.
- Để đếm các bản sao, Click tiếp thêm ở Giá trị rồi chọn COUNT ở mục Tóm tắt theo. Sau đó số lượng bản sao trùng lặp sẽ được hiển thị.
Loại bỏ các bản sao – công cụ dọn dẹp dữ liệu tiêu chuẩn
Trang tính có một công cụ nhỏ, đơn giản để loại bỏ các bản sao trùng lặp. Nó được nằm trong tab Dữ liệu> Dọn sạch dữ liệu:
Cách sử dụng của nó rất đơn giản. Bạn chỉ cần chỉ định xem bảng của mình có hàng tiêu đề hay không và chọn tất cả các cột sẽ được kiểm tra xem có trùng lặp hay không:
Sau đó hãy nhấp vào nút Xóa hàng trùng lặp và công cụ sẽ tìm và xóa các hàng trùng lặp khỏi bảng Google Trang tính của bạn và cho biết còn lại bao nhiêu hàng duy nhất:
Đó là những cách để có thể tìm và xóa các dữ liệu trùng lặp trong google trang tính. Hãy chọn một cách phù hợp với bạn để sử dụng nhé.
